// Image3D - Based on Zoom by REAS <http://reas.com>
// 
// Author: Jorge Cardoso
// http://jorgecardoso.org
//
// 2 July 2005

/* A imagem a desenhar    */
PImage a;

/* Resolution of the image  */
int res = 2;

/* Current rotation angle  */
float rotX = 0;
float rotY = 0;

/* Origin of the image on screen  */
int originX;
int originY;

void setup() 
{
    size(400, 300, P3D);

    a = loadImage("arc.jpg");
    
    /* calculate the origin of the image on the screen  */
    originX = a.width/2;
    originY = a.height/2;  
    
    framerate(15);
}

void draw() 
{
    background(0);
        
    /* rotate around the center of the screen, a bit to the back */
    translate(width/2, height/2, 0);
    rotateX(rotX);
    rotateY(rotY);

    /* draw the image as a set of 3d lines*/
    float rr, gg, bb, tt;
    for(int i=0; i<a.height; i+=res) {
        for(int j=0; j<a.width; j+=res) {

            int c = a.pixels[i*a.width+j];
            rr = red(c); 
            gg = green(c);
            bb = blue(c);
            tt = rr+gg+bb;
            tt = tt/20.0;
            stroke(c);

            line(j-originX, i-originX, 0, j-originX, i-originY, tt );
        }
    }
    
    
    /* update the rotation angle    */
    rotX = (rotX + 0.05) %(TWO_PI);
    rotY = (rotY + 0.03) %(TWO_PI);    
}

/* change 'resolution'  */
void keyPressed() {
    if(key == '1') {
        res = 1;
    } 
    else if (key == '2') {
        res = 2; 
    } 
    else if (key == '3') {
        res = 3;
    } 
    else if (key == '4') {
        res = 4;
    } 
    else if (key == '5') {
        res = 5;
    }
}